rebrand!: Antergos NeXT -> Euri Linux

2026-08-21 21:43:47 +02:00
parent 7256fd331a
commit 0cfc149d37
1452 changed files with 599 additions and 597 deletions
@@ -0,0 +1,91 @@
+# Maintainer: Michał <ash8820@proton.me>
+
+_tag=0.14.1
+
+pkgbase=euri-live
+pkgname=('euri-live-base'
+        'euri-live-dinit'
+        'euri-live-openrc'
+        'euri-grub-live')
+pkgver=2026.08
+pkgrel=6
+pkgdesc='Euri live session'
+arch=('any')
+url="https://github.com/Euri-Linux/euri-live"
+license=('GPL')
+makedepends=('git' 'bash' 'artools-base')
+source=("git+https://gitea.artixlinux.org/artix/artix-live.git#tag=$_tag")
+sha256sums=('SKIP')
+
+pkgver() {
+   date +%Y.%m
+}
+
+build() {
+    make -C artix-live
+
+    # Don't remove calamares.desktop — we ship a branded one
+    sed -i 's/^remove_calamares_launcher$/# remove_calamares_launcher/' artix-live/bin/artix-live
+
+    # Uncomment calamares section so desktop-items copies it to localized Desktop
+    sed -i '/# if .*calamares/,/# fi/ s/^# //' artix-live/bin/desktop-items
+
+    sed -i 's/artix/euri/g; s/Artix/Euri/g' \
+        artix-live/data/grub/cfg/kernels.cfg \
+        artix-live/data/grub/cfg/variable.cfg \
+        artix-live/data/grub/cfg/grub.cfg \
+        artix-live/data/grub/cfg/defaults.cfg \
+        artix-live/data/grub/cfg/loopback.cfg \
+        artix-live/data/live.conf 2>/dev/null || true
+}
+
+package_euri-live-base() {
+    pkgdesc='Euri live base scripts'
+    depends=('artools-base' 'bash')
+
+    make -C artix-live DESTDIR=${pkgdir} install_base install_xdg
+
+    # Rename binary and fix internal references
+    sed -i 's/LIVEUSER=${LIVEUSER:-artix}/LIVEUSER=${LIVEUSER:-liveuser}/g; s|LOGFILE='\''/var/log/artix-live.log'\''|LOGFILE='\''/var/log/euri-live.log'\''|g' "${pkgdir}/usr/bin/artix-live" 2>/dev/null || true
+    mv "${pkgdir}/usr/bin/artix-live" "${pkgdir}/usr/bin/euri-live" 2>/dev/null || true
+}
+
+package_euri-live-openrc() {
+    pkgdesc='Euri live openrc init scripts'
+    depends=('euri-live-base')
+    provides=('init-euri-live')
+    conflicts=('init-euri-live' 'init-artix-live')
+
+    make -C artix-live DESTDIR=${pkgdir} install_rc
+
+    # Rename init script and fix internal references
+    sed -i 's/artix live script/euri live script/g; s|/usr/bin/artix-live|/usr/bin/euri-live|g' "${pkgdir}/etc/init.d/artix-live" 2>/dev/null || true
+    mv "${pkgdir}/etc/init.d/artix-live" "${pkgdir}/etc/init.d/euri-live" 2>/dev/null || true
+
+    install -d "${pkgdir}"/etc/runlevels/default
+    ln -sf /etc/init.d/euri-live "${pkgdir}"/etc/runlevels/default/euri-live
+    ln -sf /etc/init.d/pacman-init "${pkgdir}"/etc/runlevels/default/pacman-init
+}
+
+package_euri-live-dinit() {
+    pkgdesc='Euri live dinit init scripts'
+    depends=('euri-live-base')
+    provides=('init-euri-live')
+    conflicts=('init-euri-live' 'init-artix-live')
+
+    make -C artix-live DESTDIR=${pkgdir} install_dinit
+
+    # Rename and fix internal references in dinit service files
+    sed -i 's|/usr/bin/artix-live|/usr/bin/euri-live|g; s/artix live/euri live/g' "${pkgdir}/etc/dinit.d/artix-live" 2>/dev/null || true
+    mv "${pkgdir}/etc/dinit.d/artix-live" "${pkgdir}/etc/dinit.d/euri-live" 2>/dev/null || true
+
+    # Fix boot.d symlinks
+    rm -f "${pkgdir}/etc/dinit.d/boot.d/artix-live"
+    ln -sf ../euri-live "${pkgdir}/etc/dinit.d/boot.d/euri-live"
+}
+
+package_euri-grub-live() {
+    pkgdesc='Euri grub live'
+
+    make -C artix-live PREFIX=/usr DESTDIR=${pkgdir} install_grub
+}